New 迷路 2

New 迷路の IchigoCake BASIC 版です。
IchigoJam BASIC では動作しません。

何が 2 なのか？というと、
BASIC 画面と PanCake 画面の 2 画面になっています。

BASIC と PanCake 両方にモニタなどを接続して下さい。

プログラムも長く、1k バイトを超えています。

RUN すると BASIC 画面で迷路を線画します。
その後 PanCake 画面では拡大画面で表示されます。

矢印キーで BASIC 画面右下のゴールへ移動して下さい。

PanCake 画面では女の子になっています。

女の子がゴールで見つけたものは……？

ゴールの後、再度 RUN で迷路は毎回変化します。

モニタなどが 1 つしかない場合、10 以外の行頭 ' を外し、
ジャンパ J2 を 2-3 へ接続した状態で RUN して下さい。

全画面表示の後、SPACE キーで拡大画面に変化します。
また SPACE キーで迷路全体と拡大画面を切り替えできます。

動画はこの 1 画面切り替えで撮影しています。

Kidspod;・イチゴジャムレシピ MixJuice コンテンツでは
2 画面版と 1 画面切り替え版、両方を入れてあります。

プログラム実行中は UART 0 を使用しているため、
MixJuice を使用している時にプログラムを中断すると

MixJuice のコマンドが動作しなくなります。
UART 1 を実行する事で動作するようになります。

ゴールした時は UART 1 にしているので、正常に動作します。

2 画面版（BASIC・PanCake 同時表示）

ジャンパ J2 は 1-2 に接続して下さい。

10 'New MAZE 2
20 [102]=0:'Only IchigoCake!
30 CLS:CLV:?:UART 0
40 PC.CLEAR 0
50 'VIDEO 1:PC.VIDEO 0
60 FOR Y=2 TO 20
70 LC 2,Y:? CHR$(1);
80 LC 28,Y:? CHR$(1);:NEXT
90 FOR X=2 TO 28
100 LC X,2:? CHR$(1);
110 LC X,20:? CHR$(1);:NEXT
120 FOR X=4 TO 26 STEP 2
130 FOR Y=4 TO 18 STEP 2
140 LC X,Y:? CHR$(1);
150 K=RND(4)
160 A=X-(K=0)+(K=1)
170 B=Y-(K=2)+(K=3)
180 LC A,B:? CHR$(1);:NEXT:NEXT
190 LC 3,3:?"S";
200 LC 27,19:? CHR$(2);
210 'IF INKEY()<>32 CONT
220 X=3:Y=3:A=3:B=3
230 'VIDEO 0:PC.VIDEO 1:P=1
240 FOR W=-2 TO 2
250 FOR V=-2 TO 2
260 C=SCR(X+V,Y+W)
270 D=#64:IF C=1 D=#5D
280 PC.STAMPS 36+V*8,18+W*8,D
290 IF C<2 GOTO 330
300 IF C=2 D=#49 
310 IF C=83 D=#92
320 PC.STAMPS 36+V*8,18+W*8,D
330 NEXT:NEXT:C=SCR(X,Y)
340 PC.STAMPS 36,18,#07
350 LC X,Y:? CHR$(249);
360 IF X=27 AND Y=19 GOTO 470
370 K=INKEY():IF !K CONT
380 A=X-(K=28)+(K=29)
390 B=Y-(K=30)+(K=31)
400 'IF K<>32 GOTO 430
410 'P=1-P:VIDEO 1-P:PC.VIDEO P
420 'GOTO 370
430 IF A=X AND B=Y GOTO 370
440 IF SCR(A,B)=1 GOTO 370
450 LC X,Y:? CHR$(C);
460 X=A:Y=B:GOTO 240
470 ? CHR$(31);
480 'VIDEO 1:PC.VIDEO 0
490 UART 1

Kidspod; でプログラム参照

GitHub でプログラム参照 (再配布向け)

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/816

MicJack ダウンロード ?"MJ GKP 816

1 画面切り替え版（BASIC 全体・PanCake 拡大切り替え）

上のプログラムより 10 以外の行頭 ' を外した状態です。ジャンパ J2 は 2-3 へ接続して下さい。SPACE で画面を切り替えます。

Kidspod; でプログラム参照

GitHub でプログラム参照 (再配布向け)

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/821

MicJack ダウンロード ?"MJ GKP 821

他の方が作った IchigoCake BASIC の迷路

3D迷路-CK | SHIROのIchigoJam日記
たまたま SHIRO さんも同時期に IchigoCake BASIC（BASIC＋PanCake）2 画面で迷路を作っていました。
3D＋2D 全体表示の 2 画面になっています。IchigoCake BASIC なので長くても 1 プログラムで収まっています。

BASIC のみの迷路プログラムはいくつか製作・公開されています。迷路で紹介しています。

他のバージョン

BASIC/プログラム/迷路 - 全体画面のみ。多くのバージョンで動作します。BASIC 画面がそっくりでしょう？
BASIC/プログラム/New 迷路 - IchigoJam BASIC 1.2.2 以降。拡大画面→全体画面は見れないので難易度が高くなっています。
PanCake/JS プログラム/ New 迷路 2 - 同じ動作は IchigoLatte(JavaScript)＋PanCake 版。IchigoCake でなくても動作します。