落ちる〜

なぜ落ちているのかは分からない。

とりあえず刺さると大変そうな物体があるので、

それを避けるしかない。

急降下しているから、壁に当たってもいけない。

とにかく避けていくしかない……

こんなゲーム、昔ありましたよね？という感じの

スクロール障害物避けです。

カーソルキー左右で上にいる人を動かして、

とにかく障害物と壁を避けます。

当たってしまったらゲームオーバー。スコア表示です。

表示を極力シンプルにする事で速度を上げています。

キャラクターを変えてみるのが一つの改造方法。

4・6 キーなど、他のキーに割り当てても良いですね。

IchigoJam BASIC 0.9.4 以降では速くなりすぎるので
行 75 を追加しています。

短くするなら行 90〜100 は論理式で1行にできるでしょう。

IchigoJam BASIC 0.9.9〜

5 'ｵﾁﾙ~
10 CLS:LET X,14:LET S,0:LET Y,0
20 GOSUB 160
30 LET Y,Y+1:IF Y<>23 GOTO 20
40 IF SCR(X,1)<>0 GOTO 120
50 GOSUB 160
60 LOCATE RND(11)+9,23:? "+"
70 LOCATE X,0:? CHR$(250);
75 WAIT 5
80 LET I,INKEY()
90 IF I==28 LET X,X-1
100 IF I==29 LET X,X+1
110 LET S,S+1:GOTO 40
120 LOCATE 0,23:?
130 LOCATE X,0:? CHR$(244);
140 LOCATE 0,22:? "SCORE:";S;" ";
150 END
160 LOCATE 8,Y:? CHR$(1);
170 LOCATE 20,Y:? CHR$(1);
180 RETURN

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

IchigoJam web でプログラム実行

Kidspod; でプログラム参照

GitHub でプログラム参照 (再配布向け)

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/577

MicJack ダウンロード ?"MJ GKP 577

IchigoJam BASIC 0.7.6〜0.9.8

10 CLS:LET X,17:LET S,0:LET Y,0
20 GOSUB 160
30 LET Y,Y+1:IF Y<>26 GOTO 20
40 IF VPEEK(X,1)<>0 GOTO 120
50 GOSUB 160
60 LOCATE RND(11)+12,26:? "+"
70 LOCATE X,0:? CHR$(6);
75 ' WAIT 5 ' IchigoJam 0.9.4-
80 LET I,INKEY()
90 IF I==28 LET X,X-1
100 IF I==29 LET X,X+1
110 LET S,S+1:GOTO 40
120 LOCATE 0,26:?
130 LOCATE X,0:? CHR$(15);
140 LOCATE 0,25:? "SCORE:";S;" ";
150 END
160 LOCATE 11,Y:? CHR$(1);
170 LOCATE 23,Y:? CHR$(1);
180 RETURN

GitHub でプログラム参照 (再配布向け)

IchigoJam BIG・IchigoJam BASIC 1.2.2〜版

10 'ｵﾁﾙ~
15 IF VER()>12233 VIDEO 3
20 CLS:X=7:S=0:Y=0
30 FOR Y=0 TO 11:GOSUB 170:NEXT
40 IF VPEEK(X,1) GOTO 130
50 GOSUB 170
60 LOCATE RND(11)+3,11:? "+"
70 LOCATE X,0:? CHR$(250);
80 WAIT 5
90 I=INKEY()
100 IF I=28 LET X,X-1
110 IF I=29 LET X,X+1
120 S=S+1:GOTO 40
130 LOCATE 0,11:?
140 LOCATE X,0:? CHR$(244);
150 LOCATE 0,10:? "SCORE:";S;" ";
160 END
170 LOCATE 2,Y:? CHR$(1);
180 LOCATE 14,Y:? CHR$(1);
190 RETURN