かけ算マスター

掛け算の筆算、小学校の時に学びます。

IchigoJam であれば何度も問題を生成してくれます。

IchigoJam を使う年代としても、理想的ではないでしょうか。

IchigoJam 1.2.2 以降では VIDEO 3 で大きく表示できます。

また SWITCH 1 の液晶モジュールを用いた表示も可能です。
（プログラム終了時にスクロールします）
VIDEO 3 と同じ表示になる IchigoJam BIG の動作も可能です。

RUN すると 5 桁✕ 2 桁で掛け算が表示されます。

■ が表示される部分を数字キーで入力していきます。

九九をすれば良いのですが、繰り上がりの数に注意を要します。

正しい数値を入れると、次のところへ ■ が移ります。
誤っている場合は ■ が移動しません。
九九が終了すると、更に横線が表示され、
次は縦に足し算を行っていきます。

こうして筆算が完了し、掛け算の答えが完成したところで

OK と表示されてプログラム終了です。

RUN で新たな問題が表示されます。

大人でも計算機・電卓などを使う時代で、単純な筆算でも頭を使います、

久しぶりに掛け算の筆算で頭を使ってみるのもよろしいかと思います。

IchigoJam BASIC の変数で扱える数値は 32767 までですが、工夫次第で何桁でも扱う事ができます。

20 の A=5:B=2 の数値を変更して桁数を変更できます。それぞれ最小 1 桁、最大 16 桁になります。

掛ける数が 1 桁の場合は足し算が発生しないため、掛け算のみでプログラムを終了します。

VIDEO 3 による拡大表示は A（かけられる数）は最大 11 桁、B（かける数）は最大 5 桁までスクロールせずに使用可能です。

200・330 をコメントにすると、入力待ちする事なく、計算結果まで自動計算し、プログラムを終了します。

10 'ｶｹｻﾞﾝ ﾏｽﾀｰ
20 A=5:B=2
30 C=A:D=B:CLS
40 IF A>B C=B:D=A
50 LC B,0:FOR I=1 TO A
60 J=RND(10)
70 IF I=1 AND J=0 GOTO 60
80 ?J;:NEXT:LC C-1,1:?"x";
90 LC A,1:FOR I=1 TO B
100 J=RND(9)+1:?J;:NEXT
110 LC C-1,2:FOR I=0 TO D
120 ?CHR$(145);:NEXT
130 FOR J=1 TO B:K=0
140 FOR I=A TO 0 STEP -1:L=0
150 IF I<>0 L=SCR(B+I-1,0)-48
160 M=SCR(A+B-J,1)-48
170 N=L*M+K:O=N%10:K=N/10
180 IF I=0 AND O=0 GOTO 220
190 LC B+I-J,J+2:?CHR$(143);
200 IF INKEY()-48<>O GOTO 200
210 LC B+I-J,J+2:?CHR$(O+48);
220 NEXT:NEXT:LC 0,B+3
230 IF B=1 END
240 FOR I=1 TO A+B
250 ?CHR$(145);:NEXT:K=0
260 FOR I=A+B-1 TO 0 STEP -1
270 N=K:FOR J=1 TO B
280 M=SCR(I,J+2):IF M>0 M=M-48
290 N=N+M:NEXT
300 O=N%10:K=N/10
310 IF I=0 AND O=0 GOTO 350
320 LC I,B+4:?CHR$(143);
330 IF INKEY()-48<>O GOTO 330
340 LC I,B+4:?O;
350 NEXT
360 LC 0,B+5

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

IchigoJam web でプログラム実行

Kidspod; でプログラム参照

GitHub でプログラム参照 (再配布向け)

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/965

MicJack ダウンロード ?"MJ GKP 965

おまけ - 自動かけ算

ランダムで桁を設定し、筆算の計算式を生成した上で、計算をしていきます。

完成後、少し時間を置いて、新たな計算式を表示し、計算します。その繰り返しです。

IchigoJam でもここまでできる！というのが見られます。

ループ動作のため、Esc キーで中断して下さい。

上のプログラムより、次を変更しています。

20 A=RND(16)+1:B=RND(16)+1
200 'IF INKEY()-48<>O GOTO 200
230 IF B=1 GOTO 360
330 'IF INKEY()-48<>O GOTO 330
360 WAIT 300:RUN

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

IchigoJam web でプログラム実行

他の人が作ったプログラム

かけ算の筆算については、他の人もプログラムを制作・公開しています。

プログラミングで学ぶ算数、筆算アルゴリズムを実装せよ | 福野泰介の一日一創
アルゴリズムとしてかけ算の筆算を自動で行います。プログラム上 8 桁まで対応しているようです。IchigoJam web で実行可能。