New 迷路

IchigoJam BASIC 1.2.2 より採用されている
VIDEO の拡大表示を用いた迷路です。

実行すると迷路を生成します。
左上「S」がスタート、右下がゴールです。

ゴールまでの経路を覚えておきましょう。

スペースキーを押すと画面が切り替わります。

これ、迷路が拡大表示されています！

先程覚えた経路を頼りに矢印キーで移動して下さい。

スクロールして迷路を移動していきます。

ゴールにたどり着ければプログラム終了なので

再度 RUN（F5 キー）で新たな迷路を生成します。

LIST を表示したり、他のプログラムを実行する場合は

まず VIDEO 1（F8 キー）で通常の表示に戻して下さい。

拡大画面での画面クリアは表示領域だけが対象で、
画面外はクリアされずに残ります。これを活用し、

VIDEO 1（通常サイズ）で線画した迷路を
VIDEO 5（拡大画面）では COPY で写しています。

生成する際の迷路で画面の上が空いているのは
この領域を VIDEO 5 で使用するためです。

2019年4月19日より IchigoCake BASIC 対応になりました。

IchigoJam BASIC・IchigoCake BASIC 共に動作するよう
プログラムを改善してあります。

10 'New MAZE
20 VIDEO 1:CLS:CLV:CLP
30 FOR X=2 TO 28
40 LC X,4:?CHR$(1)
50 LC X,20:?CHR$(1):NEXT
60 FOR Y=4 TO 20
70 LC 2,Y:?CHR$(1)
80 LC 28,Y:?CHR$(1):NEXT
90 FOR X=4 TO 26 STEP 2
100 FOR Y=6 TO 18 STEP 2
110 LC X,Y:?CHR$(1)
120 R=RND(4)
130 A=X-(R=0)+(R=1)
140 B=Y-(R=2)+(R=3)
150 LC A,B:?CHR$(1):NEXT:NEXT
160 LC 3,5:?"S"
170 LC 27,19:?CHR$(3)
180 IF INKEY()<>32 CONT
190 VIDEO 5:X=3:Y=5
200 FOR B=-2 TO 2
210 C=#900+(Y+B)*32+X-3
220 COPY #900+(B+2)*8,C,7:NEXT
230 LC 3,2:?CHR$(249);
240 IF X=27 AND Y=19 END
250 LC 0,5
260 K=INKEY():IF !K CONT
270 A=X-(K=28)+(K=29)
280 B=Y-(K=30)+(K=31)
290 IF A=X AND B=Y GOTO 260
300 C=#900+B*32+A
310 IF PEEK(C)=1 GOTO 260
320 X=A:Y=B:GOTO 200

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

IchigoJam web でプログラム実行

Kidspod; でプログラム参照

GitHub でプログラム参照 (再配布向け)

MixJuice ダウンロード ?"MJ GET kidspod.club/mj/608

MicJack ダウンロード ?"MJ GKP 608

次の行を加えると壁が多くなり、難易度が上がります。

145 IF SCR(A,B)=1 GOTO 120

次の行を変更すると、右・下が 1 文字分広く表示され、難易度が下がります。

200 FOR B=-2 TO 3
220 COPY #900+(B+2)*8,C,8:NEXT
250 LC 0,-1

他のバージョン

PanCake/BASIC プログラム/New 迷路 2 - IchigoCake BASIC 専用。BASIC と PanCake の 2 画面表示バージョン。
BASIC/プログラム/迷路 - 拡大表示しないバージョン。古い IchigoJam BASIC でも動作可