GIVE UP!
なぜ伸びていくんだ、なぜ止まらないんだ、
なぜ障害物がでてくるんだ、あ、あ、あ、あああああ……
スネーク型ゲーム、よくあったものです。
開始すると中央の ■ が伸びていきます。
＋ と周辺の壁を避けて長生きシて下さい。
ぶつかってしまうとゲームオーバーです。
ゲームオーバー時はプログラムが終了するので、
再度行う場合は RUN して下さい。
改造はキャラクター変更、キー操作変更、
ゲームオーバー時の動作など、いろいろできますね。
IchigoJam BASIC のバージョンが新しい程
処理速度がはやいので、難易度も高くなっています。
必要に応じて WAIT を入れて下さい。
IchigoJam BASIC 0.9.9〜
5 'GIVE UP!
10 CLS:LET X,0:LET Y,0
20 LOCATE 0,Y:? CHR$(1);
30 LOCATE 31,Y:? CHR$(1);
40 LET Y,Y+1:IF Y<>23 GOTO 20
50 LOCATE X,0:? CHR$(1);
60 LOCATE X,22:? CHR$(1);
70 LET X,X+1:IF X<>32 GOTO 50
80 LET S,0:LET X,16:LET Y,11
90 LET M,0:LET N,1
100 LOCATE X,Y:? CHR$(2);:LET C,0
105 WAIT 5:'IchigoJam BASIC 1.0.0+
110 LET R,RND(29)+1:LET Q,RND(21)+1
120 IF (R>X-3)*(R<X+3) LET C,C+1
130 IF (Q>Y-3)*(Q<Y+3) LET C,C+1
140 IF C==2 GOTO 110
150 LC R,Q:? "+";
160 LET I,INKEY()
170 IF I==28 LET M,-1:LET N,0
180 IF I==29 LET M,1:LET N,0
190 IF I==30 LET M,0:LET N,-1
200 IF I==31 LET M,0:LET N,1
210 LOCATE 0,23:? "SCORE ";S;
220 LET X,X+M:LET Y,Y+N
230 IF SCR(X,Y)<>0 GOTO 250
240 LET S,S+1:GOTO 100
250 LOCATE X,Y:? CHR$(244);
260 LOCATE 10,23:END
IchigoJam web でプログラムを実行します。
このQRコードはアクセス解析のためにCookieを使用しています。
アクセス解析は匿名で収集されており、個人を特定するものではありません。
この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/578
MicJack ダウンロード ?"MJ GKP 578
IchigoJam BASIC 0.7.6〜0.9.8
10 CLS:LET X,0:LET Y,0
20 LOCATE 0,Y:? CHR$(1);
30 LOCATE 35,Y:? CHR$(1);
40 LET Y,Y+1:IF Y<>26 GOTO 20
50 LOCATE X,0:? CHR$(1);
60 LOCATE X,25:? CHR$(1);
70 LET X,X+1:IF X<>36 GOTO 50
80 LET S,0:LET X,17:LET Y,13
90 LET M,0:LET N,1
100 LOCATE X,Y:? CHR$(2);:LET C,0
110 LET R,RND(33)+1:LET Q,RND(22)+1
120 IF (R>X-3)*(R<X+3) LET C,C+1
130 IF (Q>Y-3)*(Q<Y+3) LET C,C+1
140 IF C==2 GOTO 110
150 LC R,Q:? "+";
160 LET I,INKEY()
170 IF I==28 LET M,-1:LET N,0
180 IF I==29 LET M,1:LET N,0
190 IF I==30 LET M,0:LET N,-1
200 IF I==31 LET M,0:LET N,1
210 LOCATE 0,26:? "SCORE ";S;
220 LET X,X+M:LET Y,Y+N
230 IF VPEEK(X,Y)<>0 GOTO 250
240 LET S,S+1:GOTO 100
250 LOCATE X,Y:? CHR$(15);
260 LOCATE 10,26:END他のバージョン
- BASIC/プログラム/GIVE UP! 2 - BASIC 1.3b9 以降版。原作に近い動作になりました
- PanCake/BASIC プログラム/GIVE UP! - PanCake+IchigoJam (BASIC) 版
- プログラム - MSX JAPAN▉ - MSX2 版 (1995 年作)
- プログラム - POKE COM - PC-G850 シリーズ版
イチゴジャム レシピ では jig.jp・B Inc.・na-s.jp (株式会社ナチュラルスタイル)
の確認・了承を得て商標・公式ロゴを使用しています。
IchigoLatte is a registered trademark in Japan
of the Natural Style Co,Ltd. (na-s.jp)
IchigoJam Recipe (イチゴジャム レシピ) has confirmation and approval
for the use of trademarks and official logos of jig.jp, B Inc. and na-s.jp.
SkyBerryJAM は 栃木県立栃木工業高等学校 が管理する登録商標であり、
SkyBerryJAM は 栃木県立栃木工業高等学校 の商標です。
managed by Tochigi Technical High School (Tochiko)
Raspberry Pi は
Raspberry Pi 財団 の登録商標です。
Raspberry Pi is a registered trademark or
trademark of
the Raspberry Pi Foundation.
"RISC-V" の商品名は RISC-Vインターナショナル が管理する登録商標です。
The “RISC-V” trade name is a registered trade mark of
RISC-V International.
イチゴジャム レシピ は jig.jp・B Inc.・na-s.jp・
IchigoJam Recipe (イチゴジャム レシピ) is NOT an official website
by jig.jp, B Inc., na-s.jp and PCN (Program Club Network).
クリエイティブ・コモンズ 表示 4.0 国際 ライセンス
(シェアボタン、PanCake 公式ロゴ、MSX フォント、
(Share button, PanCake Offical Logo, MSX font, Nyan Cat,
Denshi Kousaku Magazine & Micom BASIC Magazine Images,
Petit Computer Images, KDDI / Jimdo footer and
objects with the license specification are excluded)