バルーントリップ


SCROLL が付いたら作ってみたかった!

ふっ、ふっ、ふうせんぅ〜〜〜 🎈😍 ←風船大好き

 

右に風船で浮かんでいるキャラクター、

(というか、キャラクターも風船っぽい?)

左からトゲトゲがやってきますので、よけましょう。

IchigoJam 本体のボタンを押して上昇、離して下降です。

トゲトゲに当たる以外に画面上下端に行っても

ゲームオーバーとなります。

最初はスピードが遅くトゲトゲも少ないのですが、

だんだんとスクロールが速くなり、

トゲトゲも多くなって、難しくなってきます。

 

INKEY() ではキーリピートがあるため、
意図せず上昇・下降する可能性があるので、

あえて BTN() にしてあります。



IchigoJam BASIC 0.9.9〜

5 'バルーントリップ
10 CLS:CLV:LET Y,11:LET L,10
20 SCROLL 1
30 IF S%L==0 LC 0,RND(23):? "+";
40 LC 31,Y:? CHR$(232);
50 LC 31,Y+1:? CHR$(237);:WAIT L
60 LET I,BTN():LET Y,Y-I+(I==0)
70 IF VPEEK(30,Y) GOTO 130
80 IF VPEEK(30,Y+1) GOTO 130
90 IF Y==0 OR Y==22 GOTO 130
100 LET S,S+1
110 IF S%25==0 AND L>1 LET L,L-1
120 GOTO 20
130 SCROLL 1
140 LC 31,Y:? CHR$(244);
150 LC 31,Y+1:? CHR$(244);
160 LC 0,23:? "SCORE ";S;" ";:END

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

MixJuice ダウンロード ?"MJ GET 15JM.LI/K/591

MicJack ダウンロード ?"MJ GKP 591


 

IchigoJam BASIC 1.0.0 beta 9 以降ではキーボード対応が可能です。

 

60 LET I,BTN()+BTN(SPACE):LET Y,Y-I+(I==0)

これでスペースキーを使用できます。BTN() で IchigoJam の本体ボタンも使用可能です。


IchigoJam BASIC 0.9.7〜0.9.8

10 CLS:CLV:LET Y,11:LET L,10
20 SCROLL 1
30 IF S%L==0 LC 0,RND(25):? "+";
40 LC 35,Y:? CHR$(11);
50 LC 35,Y+1:? CHR$(12);:WAIT L
60 LET I,BTN():LET Y,Y-I+(I==0)
70 IF VPEEK(34,Y) GOTO 130
80 IF VPEEK(34,Y+1) GOTO 130
90 IF (Y==0)+(Y==23) GOTO 130
100 LET S,S+1
110 IF (S%25==0)*(L>1) LET L,L-1
120 GOTO 20
130 SCROLL 1
140 LC 35,Y:? CHR$(15);
150 LC 35,Y+1:? CHR$(15);
160 LC 0,26:? "SCORE ";S;" ";:END

IchigoJam BASIC 0.9.8 ではキャラクターコードが変わっているため、下記に変更して下さい。

40 LC 35,Y:? CHR$(232);
50 LC 25,Y+1:? CHR$(237);:WAIT L
140 LC 35,Y:? CHR$(244);
150 LC 35,Y+1:? CHR$(244);

解説

やっぱり人が飛んでる状態が良いな〜と思うなら、50 を変えます。

50 LC 35,Y+1:? CHR$(5); (0.9.7)

50 LC 35,Y+1:? CHR$(249); (0.9.8〜)

L が難易度です。30 でトゲトゲの出現、60 で速さ、100 で難易度上げを調整できます。

 

1.0.0beta9 より BTN コマンドでキーボードの一部キーに対応しています。
例えば 60 の頭を LET I,BTN(SPACE) とする事でスペースキーで動作が可能です。

 

また、周辺機器のボタンも使用可能です。(できればこれを推奨します)

GND と BTN 端子で接続したボタンで操作できます。

また 60 の頭を LET I,!IN(1) に変えると、代わりに IN1 に接続したボタンを使用できます。

(押してない時に 1、押すと 0 になるので、! を付けて反転しています)

1.0.0 beta7 より IN1・2・4 端子はプルダウン→プルアップ変更が行われています。

それ以前のバージョンでは 0・1 が逆に返ってくるので、LET I,IN(1) と ! をなくす必要があります。


他の方が作ったバルーントリップ

  • Balloon Night | Kidspod;
    yum さん公開。慣性があるので難易度が高いです。岩田元任天堂社長の追悼を兼ねて公開されました。