お絵かきロジック


ののぐらむ・イラストロジック・ピクロスなどの

名称でも知られています。IchigoJam で作ってみました。

 

RUN すると縦・横で数字が出てきます。

これが縦・横で ■ で塗りつぶす数です。

ヒントを元に塗りつぶしてデザインを完成して下さい。

完成すると OK 表示でプログラム終了です。

  • 方向 キー - カーソル移動
    (左と右、上と下がつながっています)
  • SPACE キー - ■ を置く・消す
    (完成した時はプログラムが終了します)
  • X キー - ✕ を置く・消す
    (■ がない場所を確定できます)

最初からやりなおす場合は STOP でプログラムを中断して、

CLP:RUN で同じデザインを行えます。
(PCG が変化しているため、RUN のみは不具合が発生します)

別のデザインにしたい場合は CLP:A=0:RUN として下さい。

完成して終了した時は、普通に RUN で別のデザインになります。(乱数選択なので、まれに同じデザインの場合があります)

 

プログラム単体では IchigoJam 内蔵フォントを使用します。

一部ヒントだけでは完成できないデザインがありますが、IchigoJam のキャラクター番号 224~255 のどれかです。

 


 

オリジナルデザインも可能です。キャラクタエディタ などで作成したデータを使用できます。
次のように実行します。最初からやりなおす場合も同じ実行方法です。
例えば出力結果が 14,31,31,31,14,8,16,224 であれば、次で実行します。

POKE 255*8,14,31,31,31,14,8,16,224:A=255:RUN

A の値はキャラクターを変更できるキャラクター番号 224~255 を使用できます。

上では 10 進数表記ですが、16 進数も使用可能です。

他のプログラムから LRUN も可能です。別途拡張デザインの公開も検討しています。

 

10 'オエカキ ロジック
20 IF A<224 A=RND(32)+224
30 CLS:VIDEO 3
40 FOR Y=0 TO 7:C=219
50 ?CHR$(C,C,C,C,C,C,C,C);
60 C=0:D=PEEK(A*8+Y)
70 IF D&128 C=C+1:GOTO 90
80 IF C ?C;:C=0
90 D=D<<1:IF D GOTO 70
100 IF C ?C;
110 ?:NEXT
120 FOR X=0 TO 7:B=8:C=0
130 FOR Y=0 TO 7
140 D=PEEK(A*8+Y)<<X
150 IF D&128 C=C+1:GOTO 170
160 IF C LC X,B:?C;:B=B+1:C=0
170 NEXT
180 IF C LC X,B:?C;
190 NEXT
200 COPY #800,A*8,8
210 COPY A*8,0,8
220 X=4:Y=4:LC 13,0:?CHR$(A)
230 O=0:FOR C=0 TO 7
240 D=PEEK(#800+C)
250 IF D=PEEK(A*8+C) O=O+1
260 NEXT
270 IF INKEY() CONT
280 IF O=8 CLK:A=0:LC 14,9:END
290 LC X,Y,1
300 K=INKEY():IF !K CONT
310 X=(X-(K=28)+(K=29)+8)%8
320 Y=(Y-(K=30)+(K=31)+8)%8
330 IF K<>32 GOTO 410
340 IF SCR(X,Y)<>219 GOTO 360
350 ?CHR$(2,28);:GOTO 380
360 IF SCR(X,Y)<>2 GOTO 270
370 ?CHR$(219,28);
380 C=PEEK(A*8+Y)
390 POKE A*8+Y,C^(1<<(7-X))
400 GOTO 230
410 IF(K<>88)*(X<>120)GOTO 270
420 IF SCR(X,Y)<>219 GOTO 440
430 ?CHR$(120,28);:GOTO 270
440 IF SCR(X,Y)<>120 GOTO 270
450 ?CHR$(219,28);:GOTO 270

IchigoJam web でプログラムを実行します。

このQRコードはアクセス解析のためにCookieを使用しています。

アクセス解析は匿名で収集されており、個人を特定するものではありません。

この機能はCookieを無効にすることで収集を拒否することができますので、
お使いのデバイスのブラウザの設定をご確認ください。

MixJuice ダウンロード ?"MJ GET 15J.IN/961

MicJack ダウンロード ?"MJ GKP 961