PanCake に備わっているスプライト画像を表示します。
プログラムを実行した時は 00〜0f の表示で、
2段あるうちの上が 00〜09、下が 0a〜0f です。
その後キー入力待ちとなります。
背景色を変えたい場合は 50 にある 1F の
「F」を変えます。(0〜f なので、10〜1F が有効)
ちなみに「1」を「0」にすると、
PanCake 備え付けの画像になります。(00〜07 が有効)
HEX$() を使用せず、
キー入力を生かして CHR$() で出力しているため、
IchigoJam BASIC 対応も広くしてあります。
10 'PanCake Output Sprite
20 IF VER()>11000 UART 1
30 CLV:?"PANCAKE RESET":K=48
40 VIDEO 0:?"PANCAKE VIDEO 01
50 ?"PANCAKE SPRITE START 1F
60 ?"PANCAKE SPRITE CREATE 0";
70 ?CHR$(I+48,32,K,I+48)
80 ?"PANCAKE SPRITE MOVE 0";
90 ?CHR$(I+48,32,I/2+48);
100 ?CHR$((I%2)*8+48);" 0E
110 I=I+1:IF I<10 GOTO 60
120 ?"PANCAKE SPRITE CREATE 0";
130 ?CHR$(I+55,32,K,I+55)
140 ?"PANCAKE SPRITE MOVE 0";
150 ?CHR$(I+55,32,I/2+43);
160 ?CHR$((I%2)*8+48);" 17
170 I=I+1:IF I<16 GOTO 120
180 K=INKEY():I=0
190 IF(K>47)*(K<58)GOTO 60
200 IF K=65 GOTO 60
210 IF K=97 K=K-32:GOTO 60
220 IF(K<>32)*(K<>10)GOTO 180
230 VIDEO 1:?"PANCAKE VIDEO 00"
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/615
MicJack ダウンロード ?"MJ GKP 615
CakeRes✕レトロゲームズはスプライトが 00~ef なので、専用プログラムにしてあります。
10 'ResXレトロ Output Sprite
20 UART 1:CLV:PC.RESET:K=48
30 VIDEO 0:PC.VIDEO 1
40 PC.SSTART #1F
50 ?"PC SPRITE CREATE 0";
60 ?CHR$(I+48,32,K,I+48)
70 ?"PC SPRITE MOVE 0";
80 ?CHR$(I+48,32,I/2+48);
90 ?CHR$((I%2)*8+48);" 0E
100 I=I+1:IF I<10 GOTO 50
110 ?"PC SPRITE CREATE 0";
120 ?CHR$(I+55,32,K,I+55)
130 ?"PC SPRITE MOVE 0";
140 ?CHR$(I+55,32,I/2+43);
150 ?CHR$((I%2)*8+48);" 17
160 I=I+1:IF I<16 GOTO 110
170 K=INKEY():I=0
180 IF K>47 AND K<58 GOTO 50
190 IF K>96 AND K<102 K=K-32
200 IF K>64 AND K<70 GOTO 50
210 IF K<>32 AND K<>10 GOTO 170
220 PC.VIDEO 0:VIDEO 1
MixJuice ダウンロード ?"MJ GET kidspod.club/mj/818
MicJack ダウンロード ?"MJ GKP 818
SkyBerryJAM は 栃木県立栃木工業高等学校 が管理する登録商標であり、
SkyBerryJAM は 栃木県立栃木工業高等学校 の商標です。
Raspberry Pi は
Raspberry Pi 財団 の登録商標です。
Raspberry Pi is a registered trademark or
trademark of
the Raspberry Pi Foundation.
"RISC-V" の商品名は RISC-Vインターナショナル が管理する登録商標です。
The “RISC-V” trade name is a registered trade mark of
RISC-V International.